DECLARE @matchDetails TABLE (
	[MatchID] INT
	, [SegmentID] INT
	, [playerStart] INT
	, [timeStart] DECIMAL(9,3)
	, [timeEnd] DECIMAL(9,3)
	, [timeInPoss] DECIMAL(8,3)
	)
INSERT @matchDetails
      SELECT 6824,	0,	592,	0.400,	1.300,	0.900
UNION SELECT 6824,	0,	592,	1.300,	3.600,	2.300
UNION SELECT 6824,	0,	592,	3.600,	10.000,	6.400
UNION SELECT 6824,	0,	1519,	3.600,	5.500,	1.900
UNION SELECT 6824,	0,	1519,	5.500,	9.200,	3.700
UNION SELECT 6824,	0,	847,	9.200,	11.600,	2.400
UNION SELECT 6824,	0,	658,	11.600,	13.200,	1.600
UNION SELECT 6824,	0,	592,	13.600,	13.900,	1.000
UNION SELECT 6824,	0,	592,	13.900,	14.000,	2.300
UNION SELECT 6824,	0,	1519,	14.900,	15.600,	2.900
UNION SELECT 6824,	0,	1519,	15.600,	17.600,	3.700

; WITH combinedRows (
	[MatchID]
	, [SegmentID]
	, [playerStart]
	, [timeStart]
	, [timeEnd]
	, [timeInPoss]
	, [level]
	, [rowID]
	)
AS (
	-- Anchor Definition (The rows with no preceeding row with same startend date
	-- As their start Date
	SELECT
		md.[matchID]
		, md.[segmentID]
		, md.[playerStart]
		, md.[timeStart]
		, md.[timeEnd]	
		, CAST(md.[timeInPoss] AS DECIMAL(9,3))
		, 0 AS [level]
		, NEWID() AS [rowID]
	FROM
		@matchDetails md
	WHERE
		NOT EXISTS (
			SELECT 1
			FROM @matchDetails md2
			WHERE
				md2.[matchId] = md.[matchID]
				AND md2.[playerStart] = md.[playerStart]
				AND md2.[segmentID] = md.[segmentID]
				AND md2.[timeEnd] = md.[timeStart]
			)
	
	-- Recusive Definition
	UNION ALL SELECT
		cr.[matchID]
		, cr.[segmentID]
		, cr.[playerStart]
		, cr.[timeStart]
		, md.[timeEnd]
		, CAST(cr.[timeInPoss] + md.[timeInPoss] AS DECIMAL(9,3))
		, cr.[level] + 1
		, cr.[rowId]
	FROM
		combinedRows cr
		JOIN @matchDetails md ON
			md.[matchID] = cr.[matchId]
			AND md.[playerStart] = cr.[playerStart]
			AND md.[segmentID] = cr.[segmentID]
			AND md.[timeStart] = cr.[timeEnd]
	)
SELECT
	[matchId]
	, [segmentID]
	, [playerStart]
	, [timeStart]
	, [timeEnd]
	, [timeInPoss]
FROM
	(
	SELECT
		[matchId]
		, [segmentID]
		, [playerStart]
		, [timeStart]
		, [timeEnd]
		, [timeInPoss]
		, ROW_NUMBER() OVER( PARTITION BY [rowId] ORDER BY [level] DESC ) AS [rowPos]
	FROM
		combinedRows
	)
	cr
WHERE
	cr.[rowPos] = 1
ORDER BY
	cr.[matchId]
	, cr.[playerStart]

;WITH Orders
AS
(
	SELECT MatchID, SegmentID, PlayerStart, TimeStart, TimeEnd, TimeinPoss
		,ROW_NUMBER() OVER (PARTITION BY MatchID, SegmentID ORDER BY TimeStart)
			- ROW_NUMBER() OVER (PARTITION BY MatchID, SegmentID, PlayerStart ORDER BY TimeStart) AS OrderDiff
	FROM YourTable
)
, OrdersGroup
AS
(
	SELECT MatchID, SegmentID, PlayerStart, OrderDiff
		,MIN(TimeStart) AS TimeStart
		,MAX(TimeEnd) AS TimeEnd
		,SUM(TimeinPoss) AS TimeinPoss
	FROM Orders
	GROUP BY MatchID, SegmentID, PlayerStart, OrderDiff
)
SELECT MatchID, SegmentID, PlayerStart, TimeStart, TimeEnd, TimeinPoss
FROM OrdersGroup
ORDER BY TimeStart