-- TESTDATA
CREATE TABLE #PaanBazaar
(
	PAN INT,
	ProgramId VARCHAR(32),
	TrasactDate DATETIME
);
INSERT INTO #PaanBazaar VALUES
('1','A','20110101'),
('2','B','20110102'),
('1','A','20110202'),
('3','C','20110203'),
('1','A','20110304'),
('3','C','20110304'),
('4','D','20110305');
GO

-- QUERY
DECLARE @startDate DATE; SET @startDate = '20110101';
DECLARE  @endDate DATE; SET @endDate = '20111201';
;WITH calendar AS
(
	SELECT @startDate AS Dt 
	UNION ALL 
	SELECT DATEADD(MONTH,1,Dt) FROM calendar
	WHERE Dt < @endDate
)
SELECT
	c.Dt,
	r.Repeated,
	d.Deleted,
	a.Added
FROM
	calendar c
	OUTER APPLY
	(
		SELECT COUNT(*) AS Repeated FROM #PaanBazaar p1 
		WHERE 
		c.Dt = DATEADD(month,DATEDIFF(month,0,p1.TrasactDate),0)
		AND EXISTS (SELECT * FROM #PaanBazaar p2 WHERE p1.PAN = p2.PAN
			AND c.Dt=DATEADD(month,DATEDIFF(month,0,p2.TrasactDate)+1,0))
	) r
	OUTER APPLY
	(
		SELECT COUNT(*) AS Deleted FROM #PaanBazaar p1 
		WHERE 
		c.Dt = DATEADD(month,DATEDIFF(month,0,p1.TrasactDate)+1,0)
		AND NOT EXISTS (SELECT * FROM #PaanBazaar p2 WHERE p1.PAN = p2.PAN
			AND DATEADD(month,DATEDIFF(month,0,p2.TrasactDate),0)=c.Dt)
	) d
	OUTER APPLY
	(
		SELECT COUNT(*) AS Added FROM #PaanBazaar p1 
		WHERE 
		c.Dt = DATEADD(month,DATEDIFF(month,0,p1.TrasactDate),0)
		AND NOT EXISTS (SELECT * FROM #PaanBazaar p2 WHERE p1.PAN = p2.PAN
			AND c.Dt=DATEADD(month,DATEDIFF(month,0,p2.TrasactDate)+1,0))
	) a;
GO

-- CLEANUP
DROP TABLE #PaanBazaar;
GO